notifications problem

[Tack]

Hello,

I've recently stumbled upon a very weird problem regarding the notifications. I'll explain exactly how it goes.

In my main application i have a couple of components, like this:

<view:Component1 ... />
<view:Component2 ... />
<view:Component3 ... />

//the namespace xmlns:view="com.view.components.*" is included the <Application> tag

Each of these components have their own mediators registered in the StartupCommand.

All good so far, if i run the application like this (without any notifications), all mediators are responding perfectly.

HOWEVER, when i add notifications to the mediators, only the first component is receiving and executing them, none of the other component do (whether it's the same notification or different ones). If i delete the first component, then the 2nd one is receiving the notifications (but not the rest) and so on.

The mediators all have different assigned names.. can someone enlighten me on this? I'm really clueless about how to fix it.

Thanks in advance.

Tack

[serka]

You'll have to provide more details. Perhaps some code?

if i run the application like this (without any notifications), all mediators are responding perfectly.

What do you mean they are responding perfectly? What are they responding to if there aren't notifications?

[puremvc]

Sounds as if you may have registered three instances of the same mediator without giving them unique names. Remember that the NAME constant is only a convenient practice when you have only one instance of a mediator to register.

-=Cliff>

[Tack]

Thanks for the replies. This is what my code looks like, it's 3 different mediators, i don't know why it's not working :|
If anyone can figure it out, i'll be very grateful!

StartupCommand.as:
facade.registerMediator(new ApplicationMediator(app));
facade.registerMediator(new LocalVideoOutputMediator(app.localVideoDisplay));
facade.registerMediator(new OnlineVideoOutputMediator(app.onlineVideoDisplay));
facade.registerMediator(new ChatMediator(app.chat));

mainApp.mxml
<mx:Application layout="absolute" xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:view="com.view.components.*" applicationComplete="facade.startup(this);" width="680" height="440">

<view:LocalVideoOutput id="localVideoDisplay" x="340" />
<view:OnlineVideoOutput id="onlineVideoDisplay" x="0" />
<view:chat id="chat" x="0" y="240" />

OnlineVideoOutputMediator.as:

:

package com.view
{
import com.ApplicationFacade;
import com.view.components.OnlineVideoOutput;

import org.puremvc.as3.interfaces.IMediator;
import org.puremvc.as3.interfaces.INotification;
import org.puremvc.as3.patterns.mediator.Mediator;

public class OnlineVideoOutputMediator extends Mediator implements IMediator
{
public static const NAME:String = 'OnlineVideoOutputMediator';

public function OnlineVideoOutputMediator(viewComponent:Object=null)
{
super(mediatorName, viewComponent);
}

override public function listNotificationInterests():Array
{
return [ApplicationFacade.STREAM_IN
];
}

override public function handleNotification(notification:INotification):void
{
switch(notification.getName())
{
case ApplicationFacade.STREAM_IN:
trace("init online webcam..");
this.onlineVideoOutput.initOnlineCam();
break;
}
}

private function get onlineVideoOutput():OnlineVideoOutput
{
        return viewComponent as OnlineVideoOutput;
}

}
}
LocalVideoOutputMediator.as:

:

package com.view
{
import com.ApplicationFacade;
import com.view.components.LocalVideoOutput;

import org.puremvc.as3.interfaces.IMediator;
import org.puremvc.as3.interfaces.INotification;
import org.puremvc.as3.patterns.mediator.Mediator;

public class LocalVideoOutputMediator extends Mediator implements IMediator
{
public static const NAME:String = 'LocalVideoOutputMediator';

public function LocalVideoOutputMediator(viewComponent:Object=null)
{
super(mediatorName, viewComponent);
}

override public function listNotificationInterests():Array
{
return [ApplicationFacade.STREAM_OUT];
}

override public function handleNotification(notification:INotification):void
{
switch(notification.getName())
{
case ApplicationFacade.STREAM_OUT:
trace("init local webcam..");
this.localVideoOutput.initLocalCam();
break;
}
}

private function get localVideoOutput():LocalVideoOutput
{
        return viewComponent as LocalVideoOutput;
}

}
}
ChatMediator.as:

:

package com.view
{
import com.ApplicationFacade;

import org.puremvc.as3.interfaces.IMediator;
import org.puremvc.as3.interfaces.INotification;
import org.puremvc.as3.patterns.mediator.Mediator;

public class ChatMediator extends Mediator implements IMediator
{
public static const NAME:String = 'ChatMediator';

public function ChatMediator(viewComponent:Object=null)
{
super(mediatorName, viewComponent);
}

override public function listNotificationInterests():Array
{
return [ApplicationFacade.STREAM_IN];
}

override public function handleNotification(notification:INotification):void
{
switch(notification.getName())
{
case ApplicationFacade.STREAM_IN:
trace("chat stream in");
break;
}
}

}
}

[Jason MacDonald]

Your super call in all 3 mediators is passing "mediatorName" instead of the "NAME" constant. Try changing that and it should work.

[Tack]

Your super call in all 3 mediators is passing "mediatorName" instead of the "NAME" constant. Try changing that and it should work.

THAT WAS IT! thank you so very much!!!